Recording data from two adxl345 sensors

would you have that max patch active whole year 24/7 ???

Not the whole here but eventually it should run on a small pc for a few month (this is in the future). It must connect to max in real time so it will effect some sounds.

and where is that humidity sensor getting in ?

I am using two ESP32S3 - one called "sender" that the ADXL345 sensor is attached to it and sends that sensor value to the other ESP32S3 called "Receiver" . to that receiver I also attached the analog moisture sensor (M1) via analog pin. This receiver is connected to the computer via USB and sends all data to MAX (ADXL345 sensor x y z values, and M1 analog value)

As you are sending a list, why do you also need IDs , like X1, Y1 etc ?

I'm using this because I might attached more adxl345 sensor in the future

there are places in your code that need a FIX.

could you give an example?

humidity sensor must be using a different board as it is not a part of that code you posted.

True. It is attached to the receiver board as I write above. Here is the Receiver board code:

#include <WiFi.h>
#include <esp_now.h>

typedef struct {
  float x;
  float y;
  float z;
} SensorData;

SensorData receivedData;
bool newDataReceived = false;

#define MOISTURE_PIN A10
#define LED_PIN LED_BUILTIN

unsigned long lastMoistureRead = 0;
const int MOISTURE_INTERVAL = 500; // read every 500ms

// LED state
bool ledState = false;
unsigned long lastLedToggle = 0;
unsigned long lastReceiveTime = 0;
const unsigned long COMM_TIMEOUT = 2000;      // ms without data = "waiting" mode
const unsigned long BLINK_WAITING = 300;     // heartbeat interval when idle
const unsigned long BLINK_ACTIVE = 1000;       // interval when receiving data

void onReceive(const esp_now_recv_info *info, const uint8_t *data, int len) {
  memcpy(&receivedData, data, sizeof(receivedData));
  newDataReceived = true;
  lastReceiveTime = millis();
}

void setup() {
  Serial.begin(115200);
  delay(1000);

  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);

  WiFi.mode(WIFI_STA);
  if (esp_now_init() != ESP_OK) { Serial.println("ESP-NOW init failed"); while(1); }
  esp_now_register_recv_cb(onReceive);

  Serial.println("Ready");
}

void loop() {
  unsigned long now = millis();

  // Decide current blink mode based on recent communication
  bool commActive = (now - lastReceiveTime) < COMM_TIMEOUT;
  unsigned long blinkInterval = commActive ? BLINK_ACTIVE : BLINK_WAITING;

  // Toggle LED at the appropriate interval
  if (now - lastLedToggle >= blinkInterval) {
    ledState = !ledState;
    digitalWrite(LED_PIN, ledState);
    lastLedToggle = now;
  }

  // Read moisture every 500ms without blocking
  if (now - lastMoistureRead >= MOISTURE_INTERVAL) {
    int raw = analogRead(MOISTURE_PIN);
    float moisture = 1.0 - (raw / 4095.0);
    Serial.print("M1 "); Serial.println(moisture, 3);
    lastMoistureRead = now;
  }

  // Process ESP-NOW data immediately when received
  if (newDataReceived) {
    Serial.print("X1 "); Serial.println(receivedData.x, 3);
    Serial.print("Y1 "); Serial.println(receivedData.y, 3);
    Serial.print("Z1 "); Serial.println(receivedData.z, 3);
    newDataReceived = false;
  }
}