[sharing] urn with gen~

A testament to the value of urn that it is worth coming back to 10 years later!

I also realized that the urn emulation in the GO book has a similar problem: the last step of one loop can end up being the 1st step of the next loop. The urn in the GO book works in a different way: on each step, swap the value at the current step with a value somewhere later in the data. So, the fix was fairly simple: on the 1st step, prevent it from swapping with the final step. I'll add that to the GO package download for the next update. In the meantime, here's the codebox in full, and patcher attached.

Data deck(32);
Param len(8, min=2, max=32);
Param loop(0.8, min=0, max=1);
History step, reset, output; 

// trigger on a rising edge
trig = change(in1 > 0) > 0; 
reset = change(in2 > 0) > 0 || reset; 

// rebuild the decl as [0, 1, 2, .. len-1]
if (change(len)) {
	for (i=0; i<dim(deck); i+=1) {
		poke(deck, i, i);
	}
}
	
if (trig) {
	// reset or move to next step:
	step = reset ? 0 : (step + 1) % len;
	reset = 0;
	
	// how many items remain in the list?
	remain = len-step;
    // special case: on step 0, prevent us from using 
    // the previous loop's final step
    if (step == 0) { remain -= 1; }
	
	// pick another item to swap with?
	looping = abs(noise()) < loop;
	if (!looping) { 
        swap = step + floor(abs(noise())*remain);
        // read them & swap them:
		a = peek(deck, swap);
		b = peek(deck, step);
		poke(deck, a, step);
		poke(deck, b, swap);
		// output the one we picked
		output = a;	
	} else {
		output = peek(deck, step);
	}
}

out1 = output; 
out2 = step;