basic linear algebra in gen?

Hi,

Several points:

- Sending a message "offset 0." to the jit.gen will only work if there is a [param offset] at the top-level of the patcher, or a "Param offset" declared in a codebox at the top-level patcher. The param embedded in a function is not externally accessible in this way. It must be passed by argument one way or another. Here's a couple of ways it can be done:

func(v, offset, amp=1)    {
    return amp*(v+offset);
}
Param offset(0);
out1 = func(in1, offset, amp=0.5);

func(v, amp=1)    {
    Param off(0);
    return amp*(v+off);    
}
Param offset(0);
out1 = func(in1, off=offset, amp=0.5);

Note that embedding a Param inside a function like this is equivalent to putting it as an argument with assignment:

func(v, off=0, amp=1)    {
    return amp*(v+off);    
}
Param offset(0);
out1 = func(in1, off=offset, amp=0.5);

This is all consistent with the vignette documentation. The important thing to keep in mind is that a Param at the top level of a codebox is equivalent to a [param] in the patcher, whereas a Param embedded within a function is equivalent to a function argument addressed by name; they are somewhat different in nature.

---

In regard to your last example patcher, I figured out that you are doing a mat3x3 * vec4 operation, but the naming confused me for a moment (it's unfortunate that "matrix" has two meaning for Jitter already, but calling your function "matrix" and the Param "param" was a bit more confusing!) In this case the function doesn't actually need a Param -- you can just pass in the 3x3 matrix as an argument. I guess I might have written it like this (note that I reversed the argument order to match the multiplication order):

// apply a 3x3 matrix transform to a vec4
// input:         4-plane vector
// transform:     9-plane vector
// return:     4-plane vector
// i.e. return transform * input
mul_mat3x3(transform, input)    {
    return    vec( input.x*swiz(transform,0) + input.y*swiz(transform,1) + input.z*swiz(transform,2),
                  input.x*swiz(transform,3) + input.y*swiz(transform,4) + input.z*swiz(transform,5),
                  input.x*swiz(transform,6) + input.y*swiz(transform,7) + input.z*swiz(transform,8), 
                 input.w);
}

// example:
Param mn(1, 0, 0, 0, 1, 0, 0, 0, 1);
out1 = mul_mat3x3(mn, in1); 

Hope that helps!